C_TEXT($1)
C_TEXT($2)
C_TEXT($0)

C_TEXT($Txt_encoding;$Txt_Target;$Txt_Path;$Txt_Buffer)
C_BLOB($Blb_Buffer)
C_TIME($Gmt_Doc)

$Txt_Target:=$1
If (Count parameters>1)
	$Txt_encoding:=$2
End if 

If (Length($Txt_encoding)=0)
	$Txt_encoding:="UTF-8"
End if 

If (Length($Txt_Target)>0)
	$Txt_Path:=Temporary folder+"encode.xml"
	If (Test path name($Txt_Path)=Is a document )
		DELETE DOCUMENT($Txt_Path)
	End if 
	$Gmt_Doc:=Create document($Txt_Path)
	If (OK=1)
		SAX SET XML OPTIONS($Gmt_Doc;$Txt_encoding;True;False)
		SAX OPEN XML ELEMENT($Gmt_Doc;"root")
		SAX ADD XML ELEMENT VALUE($Gmt_Doc;$Txt_Target)
		SAX CLOSE XML ELEMENT($Gmt_Doc)
		CLOSE DOCUMENT($Gmt_Doc)
		DOCUMENT TO BLOB($Txt_Path;$Blb_Buffer)
		If (OK=1)
			$Txt_Buffer:=BLOB to text($Blb_Buffer;Text without length )
			SET BLOB SIZE($Blb_Buffer;0)
			$pos:=Position("<root>";$Txt_Buffer)+6
			$len:=Length($Txt_Buffer)-$pos-6
			$Txt_Buffer:=Substring($Txt_Buffer;$pos;$len)
		End if 
		DELETE DOCUMENT($Txt_Path)
	End if 
End if 

$0:=$Txt_Buffer